'***************************************************************************
'Galil Motion Control Sample DMC Code
'***************************************************************************
'Description:
'Application program to create s-curve profile
'in contour mode.
'Total variable is total number of samples for move
'Dist variable is distance to travel
'***************************************************************************
Total=100;   'must be even number
Dist=25000
samples=Total/2
split1=(Total/4)
split2=((Total/4)*3)
'triangular accel value
D1=2*(Dist/2)
D2=(samples/2)*(samples/2)
TriAC=D1/D2
E1=(TriAC*samples)/2
E2=(E1*4)/samples
Jerk = E2/Total
'MG "Jerk=",Jerk
DA*[]
DM B[Total],C[Total],D[Total]
I=0
#JERK
B[I]=Jerk
I=I+1
JP#JERK,I<split1
#JERK1
B[I]=Jerk*-1
I=I+1
JP#JERK1,I<split2
#JERK2
B[I]=Jerk
I=I+1
JP#JERK2,I<Total
I=0
C[I]=B[I]
I=I+1
#ACC
C[I]=B[I]+C[I-1]
I=I+1
JP#ACC,I<Total
I=0
D[I]=C[I]
I=I+1
#VEL
D[I]=C[I]+D[I-1]
I=I+1
JP#VEL,I<Total
#GO
I=0
'for accelera - the WC is not valid due to the contour buffer
CMX
DT2;   'sets speed of playback
'CD @RND[D[I]]
#LOOP
CD @RND[D[I]];
'WC;    'Econo & Optima Only - uncomment
I=I+1
JP#LOOP,I<Total
'Comment out next two lines for Econo & Optima
#L2
JP#L2,_CM<>511;  'waits for contour move complete (Accelera only)
CD0;DT0
EN